Problem:

As the key importance of a computed field is to improve performance and also while exporting from a Data Entity, Skip Staging is the step we do more often for faster export where computed field is still needed instead of Virtual field. The difficulty here is when working on converting a display method to a  computed field which is having many interlinked methods.

On the same note, I recently received a requirement to build an entity for Cost Objects where this form has many display methods and the client always uses this Skip Staging functionality.

Solution:

I made similar Entity for physical fields using InventSum, InventDim and InventTableModule tables.

The Average Unit Cost is the field which is basically a display method that took some time to investigate and find the right solution.

And finally made the below Computed Field.

I used a select statement and using limited resources like Item and site with some case and Grouping statements.

private static server str getAvgUnitCost()
    {
        str avgUnitCost;
        str postedValue;
        str physicalValue;

        str itemId = SysComputedColumn::returnField(viewStr(InventSumBySiteEntity),
        identifierStr(InventSumBySite),
        fieldStr(InventSumBySite, ItemId));

        str siteId = SysComputedColumn::returnField(viewStr(InventSumBySiteEntity),
        identifierStr(InventSumBySite),
            fieldStr(InventSumBySite, InventSiteId));

        str dataArea = SysComputedColumn::returnField(viewStr(InventSumBySiteEntity),
        identifierStr(InventSumBySite),
            fieldStr(InventSumBySite, InventSumDataAreaId));

        avgUnitCost = strFmt(@'SELECT
                                CASE
                                WHEN (SUM(INVENTSUM.POSTEDQTY) - ABS(SUM(INVENTSUM.DEDUCTED)) + SUM(INVENTSUM.RECEIVED)) IS NULL
                                OR (SUM(INVENTSUM.POSTEDQTY) - ABS(SUM(INVENTSUM.DEDUCTED)) + SUM(INVENTSUM.RECEIVED)) = 0
                                THEN 0.0
                                ELSE
                                ABS(
                                (SUM(INVENTSUM.POSTEDVALUE) + SUM(INVENTSUM.PHYSICALVALUE)) /
                                (SUM(INVENTSUM.POSTEDQTY) - ABS(SUM(INVENTSUM.DEDUCTED)) + SUM(INVENTSUM.RECEIVED))
                                )
                                END AS AVGUNITCOST
                                FROM INVENTSUM
                                WHERE INVENTSUM.ITEMID = %1
                                AND INVENTSUM.INVENTSITEID = %2
                                AND INVENTSUM.DATAAREAID = %3
                                GROUP BY INVENTSUM.ITEMID, INVENTSUM.INVENTSITEID', itemId, siteId, dataArea);
        return avgUnitCost;
    }

The idea here is basically to give the Average Unit Cost of that item in that Site, which is equal to total sum of PostedValue and PhysicalValue which is divided by sum of Received Quantity and difference of Posted and Deducted Quantity.

If we have PhysicalValue, PostedValue or Deducted values then we can leverage SysComputedColumn Class methods.

Below is the implementation for the same

private static server str getAvgUnitCost()
    {
        str avgUnitCost;

        str postedVal = SysComputedColumn::returnField(viewStr(InventWarehouseOnHandV2Entity),
        identifierStr(InventWarehouseOnHandAggregatedView),
        fieldStr(InventWarehouseOnHandAggregatedView, PostedValue));

        str postedQty = SysComputedColumn::returnField(viewStr(InventWarehouseOnHandV2Entity),
        identifierStr(InventWarehouseOnHandAggregatedView),
        fieldStr(InventWarehouseOnHandAggregatedView, PostedQty));

        str physicalVal = SysComputedColumn::returnField(viewStr(InventWarehouseOnHandV2Entity),
        identifierStr(InventWarehouseOnHandAggregatedView),
            fieldStr(InventWarehouseOnHandAggregatedView, PhysicalValue));

        str deducted = SysComputedColumn::returnField(viewStr(InventWarehouseOnHandV2Entity),
        identifierStr(InventWarehouseOnHandAggregatedView),
            fieldStr(InventWarehouseOnHandAggregatedView, Deducted));

        str received = SysComputedColumn::returnField(viewStr(InventWarehouseOnHandV2Entity),
        identifierStr(InventWarehouseOnHandAggregatedView),
            fieldStr(InventWarehouseOnHandAggregatedView, Received));

        str totalQtyExp = strFmt('%1 - ABS(%2) + %3', postedQty, deducted, received);
        str totalValue = strFmt('%1 + %2', postedVal, physicalVal);


        avgUnitCost = SysComputedColumn::if(
            SysComputedColumn::equalExpression(totalQtyExp, SysComputedColumn::returnLiteral(0)),   // Checking if totalQtyExp is 0
            SysComputedColumn::returnLiteral(0),					                                // If 0 then return 0
            SysComputedColumn::abs(SysComputedColumn::divide(totalValue, totalQtyExp))              // Else divide both i.e., totalValue and totalQtyExp
            );

        return avgUnitCost;
    }

The actual display method can be seen at InventCostOnhandItem Form and at InventSum datasource methods with name averageCostPriceUnit(). From the UI, this can be obtained from Released Products > Manage Costs > Cost Objects > Average Unit Cost.

With this we have seen some tricky Switch statement in SQL and then used that in our X++ to write a computed method.

Happy Learning!

PS: The Entity or table names looks like standard but they aren't standard. I just used these names for demo purpose.

Here is a generic logic which gets all the dimensions for the particular order or may be any table. Lets say Sales Order or Customers or Vendors table or some Journal related tables. 
This simple method needs the default dimension as the parameter and returns us Dimension Names and its Values.

Currently the dimNames and dimValues are the container type variables defined globally in class as I have a different requirement.

private void getDimensions(DimensionDefault _defaultDimension)
{
    DimensionAttributeValueSetItem  setItem;
    DimensionAttributeValue         dimAttrValue;
    DimensionAttribute dimAttr;

    dimNames = conNull();
    dimValues = conNull();

    while select DisplayValue from setItem
        where setItem.DimensionAttributeValueSet == _defaultDimension
        join dimAttrValue
            where dimAttrValue.RecId == setItem.DimensionAttributeValue &&
            dimAttrValue.IsDeleted == false
        join Name from dimAttr
        where dimAttr.RecId == dimAttrValue.DimensionAttribute
    {
        dimNames += dimAttr.Name;
        dimValues += setItem.DisplayValue;
    }
}

Happy Learning!

Lets not wait more!

Use Case:

In a scenario where performance is considered too critical, then we need to go with this.

Scenario:

We are going to update a field of a table. This can be done using update_recordset or Query::update_recordset.

The current approach is much more faster than the above 2.

Lets say we have header and line tables, perhaps we can take as an example of SalesQuotationTable and SalesQuotationLine. We have some status on Line level.

So if the current date is equal to the Expiry date of SalesQuotationHeader, we are going to mark the Line with some status like lets say stop.

So now, lets see the code and we will understand.

//Table buffers declaration
SalesQuotationTable salesQuotationTable;
SalesQuotationLine salesQuotationLine;

//Getting and setting the current date to Expiry date Variable

TransDate expiryDate = DateTimeUtil::getSystemDate(DateTimeUtil::getUserPreferredTimeZone());


//Creating Update Object on SalesQuotationLine which generates an SQL Statement same like update_recordset tableName

var updateObject = new SysDaUpdateObject(salesQuotationLine);

//The below statement is like assigning a value or to the field like SET fieldName = "some Value"

updateObject.settingClause()
     .add(fieldStr(SalesQuotationLine, SQStatus)
     ,new SysDaValueExpression(SQStatus::Stop));

//WHERE Condition along with AND

queryObject.whereClause(
      new SysDaEqualsExpression(
          new SysDaFieldExpression(salesQuotationTable, fieldStr(SalesQuotationTable, QuotationId)),
          new SysDaFieldExpression(salesQuotationLine, fieldStr(SalesQuotationLine, QuotationId)))
           .and(
      new SysDaEqualsExpression(
          new SysDaFieldExpression(salesQuotationTable, fieldStr(SalesQuotationTable, QuotationExpiryDate)),
          new SysDaValueExpression(expiryDate))));


//JOIN

updateObject.joinClause(SysDaJoinKind::ExistsJoin, queryObject);


//Update Operation Final Execution

ttsbegin;
new SysDaUpdateStatement().update(updateObject);
​​​​​​​ttscommit;

Code Explanation:

As you guys already know, I'm updating a field using SysDa API.

Using SysDaUpdateObject, I told the system that we are going to update this table. And then assigned some value which we can say as "STOP". Then we are having a where clause, which seems for visibility, it  tricky but it is not in actual.

In the WHERE clause, I'm writing a general relation between SalesQuotationLine and SalesQuotationTable and then adding another condition with AND, checking if the Expiry Date at Header is actually equal to the current date which we found at the start.

And then I gave a join clause since I'm doing a join with Header table and made a join of Exists Join as you all know that I am a big fan of this join :)

Finally in a transaction, I called the actual update by passing the updating object as a parameter.

​​​The syntax is bit time taking to write in actual but this gives a huge boost to the total performance.

That's all about Update Operation with Joins using SysDa.
Stay Tuned!

Happy Learning :p

We have a simple logic which we can use for this conversion.

Let's say we are getting the epoch value as a string in our payload. Then we can convert first that into real and pass the value into below method and then this method returns the final output in utcdatetime format.

//The field on LHS is a utcDateTime field.

this.PaymentDateTimeConverted = InvoiceUtility::convertUnixOrEpochTimeStampToDateTime(any2Real(this.PaymDateTime));


public static utcdatetime convertUnixTimeStampToDateTime(real _seconds)
{
    System.DateTime dtDateTime = new System.DateTime(1970, 1, 1, 0, 0, 0, 0, System.DateTimeKind::Utc);
        
    dtDateTime = dtDateTime.AddSeconds(_seconds);

    // The below method converts DateTime to UtcDateTime
    return clrSystemDateTime2UtcDateTime(dtDateTime);
}

In this scenario, the traditional way of making datasource disable by using allowedit(false) and enabling a field will not work since allowedit() method will disable complete datasource. Even we cannot make just the control enabled since whole datasource is disabled.

The best way here is to disable each and every field and enable the specific field.

We no need to write disabling logic for every field nor to write some loop here to loop through all the fields of table and disable.

The Method:

We can use one standard method which serves our purpose. Below is the method for the same.

allowEditFieldsOnFormDS_W(, )

This method just requires the FormDataSource as a parameter and a boolean parameter to allow editing.

Understanding of method:

public static void allowEditFieldsOnFormDS_W(FormDataSource _dataSource, boolean _allowEdit)
    {
        var dictTable = new DictTable(_dataSource.table());
        int         cx, idx;

        for (cx = 1; cx <= dictTable.fieldCnt(); cx ++)
        {
            DictField dictField = dictTable.fieldObject(dictTable.fieldCnt2Id(cx));

            if (! dictField.isSystem())
            {
                for (idx = 1; idx <= dictField.arraySize(); idx++)
                {
                    FormDataObject dataObject = _dataSource.object(fieldId2Ext(dictField.id(), idx));
                    if (dataObject)
                    {
                        dataObject.allowEdit(_allowEdit);
                    }
                }
            }
        }
    }

This method as I said above takes, FormDataSource and a boolean as a parameter and based on the field count, this loops through all the fields and if it is not a system field like RecId or Partition, then it gets the FormDataObject from field and sets the form datasource field's allow edit property. This method is found in Global class.

This also works, let's say if you have a requirement to disable the complete SalesLine and some warehouse related or other datasource related fields should be enabled, then also allowedit() method will not work. This works in that scenario.

Implementation:

We just need to call this method with required parameters and then whichever field we need to be editable, make that field to be editable. Below is an example.

allowEditFieldsOnFormDS_W(dirPartyTable_ds, false);
      dirPartyTable_ds.object(fieldNum(DirPartyTable, KnownAs)).
           allowEdit(true);

Here we are making the DirPartyTable Form Datasource to be disabled and making KnownAs field editable.

Thats all for now!

Happy Learning!

So, let's not wait more and check how this can be done.

To achieve the above requirement, we need to subscribe to a standard delegate called checkAddSubMenuDelegate of Class SysMenuNavigationObjectFactory,

Use case here is if the Menu Item should be invisible in some specific legal entity or may be in other condition, we can follow this.

Below is the approach for the same. The condition returns a boolean value which specifies if the menuitem should be visible or invisible.

[SubscribesTo(classstr(SysMenuNavigationObjectFactory), staticdelegatestr(SysMenuNavigationObjectFactory, checkAddSubMenuDelegate))]
    public static void menuItemVisibilityHandler(SysDictMenu _rootMenu, SysDictMenu _subMenu, SysBoxedBoolean _subMenuVisibility)
    {
        if (_subMenu.isMenuItem())   //Checking if it is a menuitem
        {
            var metaElement = _subMenu.GetMenuItemMetaElement();
            if (metaElement != null)
            {
                switch (metaElement.Name)  //Checking the menuitem name and adding condition
                {
                    case menuItemActionStr(MenuItemOne):
                        _subMenuVisibility.value = /<Condition to specify>/;
                        break;
                    case menuItemDisplayStr(MenuItemTwo):
                        _subMenuVisibility.value = /<Condition to specify>/;
                        break;
                }
            }
        }
    }

In this way we can achieve this.

Happy Learning :)

As the name suggests the computed methods are computed in SQL level and adds the query directly to the View/Data entity's metadata. A computed method generates/returns a SQL query which is directly added to the View metadata.

This doesn't mean that whenever a view is executed, the computed method executes for each line. The computed method executes when the view is loaded and in SQL level. So that if any unmapped field is using this, then we can run a select in SSMS to check that field's value. This is completely different with the normal display method which is executed at runtime in X++. So that's why whenever we need to use display methods, for better performance, this is one of the ways to do instead of a display method.

So let us understand how to write a computed method or a computed column or a SysComputedColumn method.

public static server str getVendorAccountNum()
{
    str vendorAccount;

    str voucherNum = SysComputedColumn::returnField(viewStr(OURVIEWNAME),   //Pass View name in 'OURVIEWNAME'
        identifierStr(GeneralJournalEntry),                                 //Pass DataSource name
        fieldStr(GeneralJournalEntry, SubLedgerVoucher));                   //Pass the field name on which we are interested

    str dataArea = SysComputedColumn::returnField(viewStr(OURVIEWNAME),
        identifierStr(GeneralJournalEntry),
        fieldStr(GeneralJournalEntry, SubLedgerVoucherDataAreaId));


    vendorAccount = strFmt(@'SELECT TOP 1
                                  VENDTRANS.ACCOUNTNUM
                             FROM VENDTRANS
                             WHERE
                                  VENDTRANS.VOUCHER = %1
                                  AND VENDTRANS.DATAAREAID = %2,
                             voucherNum,
                             dataArea');

    return vendorAccount;

}

Above is a simple example on how to write a computed method. Many complex queries can be written this way.

A computed method returns a SQL query in string format which is then used by any field in that view/entity. Irrespective of the datatype, the computed method's return type is always a string. So, from above we are fetching the vendor account from a computed method. 

For creating a computed field, an unmapped field should be created in the view and make sure that computed column property is enabled at the properties level and add this method as a view method.

In entities also where we have read-only fields and if data is being populated from postload() method, then using a computed column instead improves the performance a lot.

This way we can create a computed method.

 So, how is this possible by X++ and Query classes?

 Let's not wait and will check the plan.

public void init()
    {
        super();

        Query query = new Query();
        SysQueryRun queryRun;

        query = CustInvoiceTrans_ds.query();
        queryRun = new SysQueryRun(new Query(query));

        queryRun.args().caller(this);
        queryRun.title("Invoice Journal Report");

        queryRun.args().allowUseOfPreloadedForm(false);
        queryRun.promptAllowAddRange(QueryAllowAdd::NoFields);

        if (queryRun.prompt())
        {
            CustInvoiceTrans_ds.query(queryRun.query());
        }

        else
        {
            element.close();
        }
        
    }

To answer all these questions, lets read this :)

 Lets says we need to insert or update the data from one table to another table where the two tables are completely different tables. Ideally we will just assign each and every field value from source to target. But lets say we have many fields. Like we cant just assign each and every field with those many fields and we have to use this in multiple places in the code. Then in general we will use buf2buf or data() methods to perform this activity.

But I have a different requirement where I need to copy all data from one table to another having same fields but 2 different tables.

 This particular scenario exists when you have some log table or else some custom workflow related tables.

To accomplish this task what I did is I customized the standard as per my requirement so this can now work with 2 different tables. Basically the buf2buf requires same table as the source and target. But here I made this work with 2 different tables using DictTable.

private void insertOrUpdateData(Common _source, Common _target)
{
	var         dictTable           = new DictTable(_source.TableId);
    DictTable   dicttableTarget     = new DictTable(_target.TableId);
    FieldId     fieldId             = dictTable.fieldNext(0);

    while (fieldId && ! isSysId(fieldId))
    {
        FieldId     fieldIdTarget;

        fieldIdTarget               = dicttableTarget.fieldName2Id(dictTable.fieldObject(fieldId).name());

        if (fieldIdTarget)
        {
            _target.(fieldIdTarget)     = _source.(fieldId);
        }
        else
        {
            fieldId                     = dictTable.fieldNext(fieldId);
            continue;
        }
        fieldId                     = dictTable.fieldNext(fieldId);
    }
}

This method can be called while insert or update and it needs the source and target tables to be passed as parameters.

Lets say may be you do not want to copy some field. So you can simply say the system not do copy for this field by below.

FieldId  fieldId     = dictTable.fieldNext(0);
const str Party      = "Party";

boolean ignoreThisField = dictTable.fieldObject(fieldId).name() != Party;

Here we are checking the field name using fieldId and saying the system if to include it or no.

The reason why we has this line of code, isSysId(fieldId) is this will skip the standard fields like RecId, RecVersion.

This method can be called while insert or update and after that based on process need to call the insert() or update() method something like below.

TableNameSource tableNameSource;
TableNameTarget tableNameTarget;

//insert();
//call the method and pass arguments
if (tableNameTarget.validatewrite())
{
      tableNameTarget.insert();
}

//update
//selecting which record to update
if (tableNameTarget)
{
       tableNameTarget.selectforupdate(true);
       //call method and pass arguments

       if (tableNameTarget.validatewrite())
       {
           ttsbegin;
           tableNameTarget.update();
           ttscommit;
       }
}

With this approach data can be copied between 2 different tables having same Field names.

We may sometimes encounter a situation where we need to use a temporary table as a datasource in a form lookup. But this is a bit tricky because it gets data on runtime, and we can't just do it in normal way like how we do for regular tables. So, this requires runtime insert of data as a temporary table doesn't contain data stored and should trigger lookup.

Business Scenario:

Let's say we have a requirement where we have some constant variables which are defined in a class as constants, and we need to give them as a lookup instead of hard coding from UI by user. As those are not enums and defined in class what I did is I inserted them to a temporary table called Inmemory table here and did the further coding of lookup. Main important thing here in we need to pass the temporary table buffer into SysTableLookup objects by using parmTmpBuffer() method.

Here is the code for the same. 

public void lookup(Object _object)
{
    EmailFieldsTmp  temp;

    temp.EmailFieldName = SendEmail::CustomerName;
    temp.insert();

    temp.EmailFieldName = SendEmail::CustomerManagerName;
    temp.insert();
  
    SysTableLookup              sysTableLookup = SysTableLookup::newParameters(tablenum(EmailFieldsTmp), _object);
    Query                       query = new Query();
    QueryBuildDataSource        queryBuildDataSource;

    queryBuildDataSource = query.addDataSource(tablenum(EmailFieldsTmp));
    sysTableLookup.addLookupfield(fieldnum(EmailFieldsTmp, EmailFieldName), true);
 
    sysTableLookup.parmQuery(query);
    sysTableLookup.parmTmpBuffer(temp);
    sysTableLookup.performFormLookup();
}

Here I just added some randomized constants with some values which will be shown for lookup. But in general if we have some set of data, we can loop and show that and assign that to SysTableLookup object. In this way this is achievable.

Please post for any questions and happy learning!

We might have scenario where we need to customize a form to add a button so that it should have multiselect capability and for example some functionality should happen on multi select like to get all selected records by user so that scenario is to send them as a list to some external service for integration.

Or we might also have a scenario so that for example if we are generating packing slip, then we only have to select all Saleslines with same warehouse. In such scenarios also we will go by multi select.

Ideal way would be to create a button by setting multi select property to yes.

But question is how to get all selected records in a form by code?

What are the best ways to do?

This can be done by either event handler like onclicked event handler or the pre coc on clicked method of the button.

Basically, we can do this by MultiSelectionHelper class. But we also have another way.

So how to do that then?

For this we need to get the formdatasource from the FormControl class and FormDataSource class as shown in the below codes.

When I have above requirements for the first time, I have written my code using while loop. For the Sales order line validation, I choose the For loop. Comparatively For loop is faster.

To not to change the basic theme of this blog, I will only explain how to do multiselect via X .

Below code gives the idea how to get the selected records on a form.

Here the main idea is to get the formdatasource and from that we need to assign that buffer to the Table buffer.

The buffer will increment with new record and shows all the records selected by the user.

With While Loop:

FormDateSource salesLine_DS;
SalesLine salesLine;

salesLine = salesLine_DS.getFirst(1) ? salesLine_DS.getFirst(1) : salesLine_DS.cursor();

while (salesLine)
{
  info(salesLine.LineNumber);
  salesLine = salesLine_DS.getNext();
}

With For Loop:

[ExtensionOf(formControlStr(SalesTable, buttonUpdateInvoice))] 
final class MYSalesTable_buttonUpdateInvoice_Extension 
{
  public void clicked() 
  {
    SalesLine salesLine;
    FormControl formButtonControl = any2Object(this) as FormControl;
    FormDataSource salesLine_ds = formButtonControl.formRun().dataSource(tableStr(SalesLine));
    for (salesLine = salesLine_ds.getFirst(1); salesLine; salesLine = salesLine_ds.getNext()) {
      //Here you can test the working by adding some unique ID. For example Sales Id and line Number in a info log.
    }
    next clicked();
  }
}

This article is originally posted here.

As we work with data, we usually have a database. So, all the actions which we perform for customization should be in such a way that it should not impact the performance of the system. We should be very careful while writing any piece of code.

For example, if we are working on SSRS reports and if the data retrieved by report is huge. Let’s assume the report is a DP based, where we will have a query which accepts inputs from the user and retrieve the data as a report. Generally speaking, user wants the report to run within no time even the report has huge data. If it takes huge time to run, it would be frustrating right?

As a developer we can understand the scenario if it is a query where user gives input, then we will have the X Query classes like QueryRun, Query etc. We generally write the code here like below to get the data from the user input.

Let's assume I have a "query" which sets based on user input.

InventTable             inventTable;
InventTrans             inventTrans;
QueryRun                queryRun;
RecordInsertList        myTableTmpList;
MyTable                 myTable;

queryRun            = new QueryRun(query);

while(queryRun.next())
{
    
    inventTable = queryRun.get(tableNum(InventTable));
    inventTrans = queryRun.get(tableNum(InventTrans));
    
    myTable.clear();
    myTable.ItemId = inventTable.ItemId;
    myTable.PostedDate = inventTrans.DatePhysical;
    myTable.ItemCreatedDate  = any2Date(inventTable.CreatedDateTime);
    myTable.insert();

}   

This code looks good and perfect, but it will call the database for each insert which will actually impact the report performance. I mean if it has 10000 lines, it will call database for each insert. Right?

So, how to tackle this?

Also, in this particular scenario we only need to use Query builder classes which are actually slower than the normal select statement in X but performance should be improved. Also, we cannot use insert_recordset here. So, is there any way to call the database only once with all the data to insert?

Solution:

One best way is to use Query builder classes along with RecordInsertList.

So, what is RecordInsertList?

As the name suggests it makes all the records which are retrieved by while or query builder into a list and finally calls the database once for the bulk insert of data. In this way we can speed up the performance of database. Simply a kind of List class.

Below is the code which explains the functionality of this using only a while loop.

Just like a normal while select, we will select all the records where the invoice date range is between given from and to date. So whatever data is retrieved it is added as an element into list and finally the list will call the insertDatabase() method which will insert all the listed data at once to the table.

class testRecordInsertList
{
    public static void main(Args  _args)
    {
        ProjInvoiceJour         projInvoiceJour;
        RecordInsertList        myTableTmpList;
        MyTable                 myTable;
        
        //initiating the list with temp table buffer
        myTableTmpList = new RecordInsertList(tableNum(MyTable), false, false, false, false, false, myTable);
            
        while select InvoiceDate InvoiceId from projInvoiceJour 
            where projInvoiceJour.InvoiceDate >= _fromdate
                && projInvoiceJour.InvoiceDate <= _todate
            {
                myTable.InvDate = projInvoiceJour.InvoiceDate;
 	            myTable.Invoice = projInvoiceJour.InvoiceId;
                myTableTmpList.add(myTable);
            }
        myTableTmpList.insertDatabase();
    }
}

So, with this all the data is retrieved and made as a list for each record and finally will call database for insertion of all records as a list.

Below is the code where I am using Query classes with while.

Let’s assume that I have a complex query called “query” which sets based on user input. For demonstration purpose I only used 2 tables for the query.

The code will be as below.

InventTable             inventTable;
InventTrans             inventTrans;
QueryRun                queryRun;
RecordInsertList        myTableTmpList;
MyTable                 myTable;

queryRun            = new QueryRun(query);
myTableTmpList      = new RecordInsertList(MyTable), false, false, false, false, 
                    false, myTable);        

while(queryRun.next())
{
    
    inventTable = queryRun.get(tableNum(InventTable));
    inventTrans = queryRun.get(tableNum(InventTrans));
    
    myTable.clear();
    myTable.ItemId = inventTable.ItemId;
    myTable.PostedDate = inventTrans.DatePhysical;
    myTable.ItemCreatedDate  = any2Date(inventTable.CreatedDateTime);
    myTableTmpList.add(myTable);

}   
myTableTmpList.insertDatabase();

When compared to speed between normal insert() and RecordInsertList, there will be huge difference. RecordInsertList is much faster than insert().

This article is originally posted here.

So, I have created extension of LedgerJournalTrans and added new fields and did the same in entity and staging table.

But out of my surprise, I cannot import the data through these new fields. I did model build, sync, regenerated mapping, refreshed entity. But nothing helped me. I can also see the data coming to staging but not to Entity or underlying tables. Then did the debug to see what actually is happening.

What’s the outcome?

On debug, I came to know that a method is written in this entity where actually the data from the staging is being copied to LedgerJournalEntity.

All the major functionality of this entity is found in this method, where I can see it copies the data from staging to target, validates the data etc. So first I tried doing COC on the methods which are found inside the present method which are responsible for insert and update of the data in LedgerJournalEntity. Only COC on update method worked but on create, COC did not work.

Then finally thought of doing a COC on complete method.

Then I did the post COC on copyCustomStagingToTarget() to achieve my requirement.

Below is the code which shows the COC on this method.

[ExtensionOf(tableStr(LedgerJournalEntity))]
final class MYLedgerJournalEntity_Extension
{
    public static container copyCustomStagingToTarget(DMFDefinitionGroupExecution _dmfDefinitionGroupExecution)
    {
        container ret;
        ret = next copyCustomStagingToTarget(_dmfDefinitionGroupExecution);
        LedgerJournalTrans ledgerJournalTrans;
        LedgerJournalEntityStaging staging;
        ledgerJournalTrans.skipDataMethods(true);

        update_recordset ledgerJournalTrans
                setting MYField1    =     staging.MYField1,
                        MYField2    =     staging.MYField2
            join staging
                    where staging.DefinitionGroup == _dmfDefinitionGroupExecution.DefinitionGroup
                    && staging.ExecutionId == _dmfDefinitionGroupExecution.ExecutionId
                    && staging.TransferStatus == DMFTransferStatus::Completed
                    && staging.JournalBatchNumber == ledgerJournalTrans.JournalNum
                    && staging.LineNumber == ledgerJournalTrans.LineNum;
        return ret;
    }

}

In this way, to populate the data into custom fields, COC on this method should be made.

What’s the issue? Why I am not able to import?

The reason why I am not able to import the data is, that the Set based processing (set based SQL operations) flag has been switched on for LedgerJournalEntity. So, data cannot be imported by normal process like how we do for other entites. So custom code is required for this.

This article is originally posted here.

Happy Learning!

Then I checked all the methods, used the find references and finally found 2 methods which are required for my purpose.

Now, lets check how can we do cancel or submit the workflow through code.

Recall / Cancel a workflow

To recall/cancel a workflow through code, simply call the static method called cancelWorkflow of Workflow class. The parameters, you need to provide here are the correlation id and a comment which we actually give when cancelling the workflow from UI.

The code looks like below.

Workflow::cancelWorkflow(workFlowTrackingTable.CorrelationId, "cancel by code");

Now the problem comes.

Where do I get the correlation Id?

It can be found in WorkflowTrackingStatusTable. To get the exact buffer, you must give a select on this table with where condition on InstanceNumber from this table.

So, the final code would be as below.

WorkflowTrackingStatusTable                 workFlowTrackingTable;

select firstonly CorrelationId from workFlowTrackingTable where workFlowTrackingTable.InstanceNumber == '002647';

Workflow::cancelWorkflow(workFlowTrackingTable.CorrelationId, "cancel by code");

So first we should find the exact record of that workflow to be submitted, then call the cancelWorkflow method.

Resubmit / Submit a workflow

To resubmit or submit a workflow, you need to call again another static method from same class called “activateFromWorkflowType”.

This can be done as below.

Workflow::activateFromWorkflowType(workflowtypestr(HcmDiscussion), hcmDiscussion.RecId, "SubmittedBy by Code", NoYes::No);

But wait.

We also have a return type here called WorkflowCorrelationId in the above static method. So, the code will be,

WorkflowCorrelationId		workflowCorrelationId;
HcmDiscussion               hcmDiscussion;

hcmDiscussion = HcmDiscussion::find(5637146584);

workflowCorrelationId = Workflow::activateFromWorkflowType(workflowtypestr(HcmDiscussion), hcmDiscussion.RecId, "SubmittedBy by Code", NoYes::No);

As my workflow is in HRM module, I am using the table called HcmDiscussion. Based on the place where we will work with the workflow, we should get the table name accordingly and we need to pass the parameters accordingly. The logic to submit workflow will be same across all modules or tables but based on the place, the table should be selected.

Coming to the method activateFromWorkflowType, the parameters to be passed are explained below.

The first one is the workflowtype for that module (if you are not able to get it you can make a find reference and find what is being using in that module), then the RecId of the table involved, comment, if activating from web yes otherwise no. We also have another parameter which has default value like curUserid(). We can also change the last parameter on requirement.

In this way we can simply cancel or submit the workflow through code. This logic can be implemented for multiple records or in batch or with different tables too.

This article is originally posted here.

Ternary operation statement is used for executing conditional code. It can be directly assigned to a variable. It is also possible to do same thing using if – else. But for if - else, it will look like a code flow which increases the code size which is not necessary.

For example, an if – else statement looks like,

int i = 10;
str output;

if (i > 2)
    {
      output = “true”;
    }
else
    {
     output = “false”;
    }
    
info(strfmt(“%1”,output)); //returns true

Here we have a variable of value 10 and if it is greater than 2 then output will be true which will appear as Infolog.

The same code can be written in little less steps and can directly assign to a variable using Ternary Operation.

int i = 10;
str output = i > 2 ? “true” : “false”;
info(strfmt(“%1”, output)); //returns true

Here I am directly assigning the value i.e., true or false to the output based on i value.

Like in the ternary operation, after equal to, the first expression is to evaluate the condition. Based on the condition, if it is true then the 2nd expression or value will be assigned to the variable or the 3rd expression or value will be assigned. So, we will get true as a Infolog since i is greater than 2.

Nested Ternary Operator

We sometimes need to write nested Ternary operation.

The below example is taken from standard Microsoft Documentation.

print( (custTable.AccountNum > "1000")
            ? ( (custTable.AccountNum < "2000")
                    ? "In interval" : "Above 2000"
              )
            : "low"
     );

The code processing logic will be if the customer account number is greater than 1000, then it goes into loop and checks if it is less than 2000. If it is less than 2000, then it prints “In interval” or if it is greater, then it prints “Above 2000”. If the customer number is less than 1000 then it prints low.

Now you must have understood the code flow.

By this, the code actually looks neat and clean with less steps.

So, with simple steps we can complete an if – else using ternary operation. So, it would be better to give the ternary the first preference and then if-else if we have a similar requirement.

The syntax is,

expression1 ? expression2 : expression3

and the explanation is, expression1 must be a Boolean expression. If expression1 is true, the whole ternary statement resolves to expression2. Otherwise, it resolves to expression3. expression2 and expression3 must be of the same type as each other.

This article is originally posted here.

For storing all the data in D365, we have a database where all data will be stored as records in backend tables. Most of the times we need to pick this data, edit or do something with this data in backend. We may create reports also. So, such times we will use select statement or a find method to retrieve the data.

So, what this find method is?

The find method is a static method at table which is used instead of a select statement in X coding. For example, to select a single record from VendTable, we will give the following select statement.

VendTable     vendTable;

select firstonly AccountNum from vendTable where vendTable.AccountNum == “Vend1”;
info(strFmt(“%1”, vendTable.AccountNum));

'firstonly' keyword as we have a single record for that particular ID and selecting only AccountNum as we require only that field to show as a info statement.

So, the above select statement returns that record where AccountNum is “Vend1”. 

This can also be done by using below find method.

VendTable  vendTable = VendTable::find(“Vend1”);
info(strFmt(“%1”, vendTable.AccountNum));

This will also return the same thing. We can use any of them.

But if we require just few fields then I would recommend using normal select statement explicitly mentioning each and every field. Because the find method will retrieve data from all the fields. If all the fields’ data is not required, then it is not necessary to use find method at such cases.

Now how to write the find method in any custom table?

You can simply copy any standard table find method and use that in your code as below.

Below is the find method for VendTable.

public static VendTable find(
        VendAccount             _vendAccount ,
        boolean                 _forupdate        = false,
        ConcurrencyModel        _concurrencyModel = ConcurrencyModel::Auto)
    {
        VendTable vendTable;

        vendTable.selectForUpdate(_forupdate);
        if (_forupdate  && _concurrencyModel != ConcurrencyModel::Auto)
        {
            vendTable.concurrencyModel(_concurrencyModel);
        }

        if (_vendAccount != '')
        {
            select firstonly vendTable
                where vendTable.AccountNum == _vendAccount;
        }

        return vendTable;
    }

This method can be copied into your table method and should be changed accordingly like in the name of VendTable, your custom table name and in the place of VendAccount, your index field name. 

Now the use of find method is, as we have 2 parameters where 2nd parameter is optional or default,

• If you just give the Vendor account number, then it will retrieve the only record with that vendor account number taking into consideration the other parameter _forupdate is false. 

• If you give both vendor number and _forupdate to true, then it will retrieve the record and update the record as well.

• The unique index can be found simply by looking at the find method as the mandatory parameters in find method are unique.

By this we can understand that a find method can be used to retrieve the data or update the data. We can also use this for finding the unique index of the table.

This is also best practice to include find method in the table.

This is originally posted here.

We have a requirement to post only specified sales lines in a Sales Order from X++. To address this requirement, I did my own analysis and achieved this with the below solution.

So lets check what is the solution for this..:)

Solution:

We can leverage the existing SalesFormLetter class for this requirement. This class is commonly used for posting Sales Orders, and it provides a convenient chooseLinesQuery() method to select specific lines. Simply passing a standard SalesUpdate query with the appropriate filters like the Sales Id and the lines numbers to this method helps us in posting specific lines.

Explanation:

Here I have created a query object for SalesUpdate query and collected the lines into a container to pass them as a range along with the Sales ID. This combined information is then used to construct a query. Once the query is built, a queryRun object is created and fed it into the chooseLinesQuery() method of the SalesFormLetter class. This method instructs the SalesFormLetter to post only the lines included in the provided range.

The below code does the Invoice Posting. Same thing can be used for Packing Slip as well.

SalesFormLetter salesFormLetter = SalesFormLetter::construct(DocumentStatus::Invoice);

if (this.parmLineNums() != conNull())
{
       Query query = new Query(queryStr(SalesUpdate));
           query.dataSourceTable(tableNum(SalesLine)).addRange(fieldNum(SalesLine, SalesId)).value(salesTable.SalesId);
       query.dataSourceTable(tableNum(SalesLine)).addRange(fieldNum(SalesLine, LineNum)).value(con2Str(this.parmLineNums()));

       SysQueryRun queryRun = new SysQueryRun(query);
       salesFormLetter.chooseLinesQuery(queryRun);
}

salesFormLetter.update(salesTable, DateTimeUtil::getSystemDate(DateTimeUtil::getUserPreferredTimeZone()), SalesUpdate::All, AccountOrder::None, NoYes::No, NoYes::No, NoYes::No, NoYes::Yes);

Using the chooseLinesQuery() method this scenario can be achieved.

PS:- To stick with the discussion, I explained or added the code only w.r.t to posting of specific line. Table buffers like SalesTable which I am using doesn't have initialization here since complete code has not been added.